home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Hardcore Gamer Resource Kit
/
Hardcore Gamer Resource Kit - Disc 2.iso
/
Pc
/
GRAVIS
/
U8GUS.ZIP
/
INSTALL.BAT
< prev
next >
Wrap
DOS Batch File
|
1994-03-29
|
2KB
|
68 lines
@echo off
cls
echo Ultima (R) VIII UltraSound Support Installation
echo.
if [%1] == [] goto usage
if not [%2] == [] goto usage
if not exist %1\u8.exe goto baddir
if not exist %1\sound\a16sbfm.dll goto baddir
if exist %1\sound\a16mt32.dll goto gooddir
:baddir
echo Ultima 8 does not appear to be installed in %1.
echo.
goto usage
:gooddir
if not exist %1\sound\dllback\a16sbfm.dll goto doback
if exist %1\sound\dllback\a16mt32.dll goto docopy
:doback
echo Backup up Sound Blaster and General MIDI music drivers
md %1\sound\dllback
copy %1\sound\a16sbfm.dll %1\sound\dllback\a16sbfm.dll > nul
copy %1\sound\a16mt32.dll %1\sound\dllback\a16mt32.dll > nul
:docopy
echo Copying in new files
copy a16gus.dll %1\sound\a16sbfm.dll > nul
copy a16gus.dll %1\sound\a16mt32.dll > nul
copy ultima8.bat %1\ultima8.bat > nul
copy loadpats.exe %1\loadpats.exe > nul
copy u8gus.ini %1\u8gus.ini > nul
echo Running LOADPATS:
loadpats -iu8gus.ini
if errorlevel==1 goto lpfail
echo.
echo Now run INSTALL in the Ultima 8 directory.
echo Set 'Sound Configuration' for 'no sound card'
echo Set 'Music Configuration' for 'Sound Blaster'
echo When prompted for a port address, select your UltraSound base address.
echo.
echo To run Ultima 8 with UltraSound support, type ULTIMA8 [ENTER].
echo Do NOT type U8 [ENTER].
echo.
echo You will now hear Ultima 8's General MIDI music.
echo.
cd %1
goto end
:lpfail
echo.
echo Error running LOADPATS. Please resolve the conflict then reinstall this
echo update.
echo.
goto end
:usage
echo Usage:
echo.
echo INSTALL dir_name [ENTER]
echo.
echo where dir_name is the directory where Ultima 8 is installed
echo.
echo e.g. INSTALL C:\ULTIMA8
echo.
:end